Titulo: Filtro para Columnas de Altavoces. Prac. N 2 CCE

*Elemento Nodo_1 Nodo_2 Valor
        
*Comentarios
*VIN   1     0   AC    1   DC   0  SIN(0 100m 1k) 

*Generador Equivalente Salida del Altavoz
VIN 10 0 ac 1
RGEN 10 1 8


*Sistema de Filtrado para Graves
L1 1 2 6.4mH
C1 2 0 12uF
RG 2 0 8

C2 1 3 10uF
L2 3 0 1.2mH

*Sistema de Filtrado para Medios
L3 3 4 0.5mH
C3 4 0 8.2uF
RM 4 0 8

*Sistema de Filtrado para Altos
C4 3 5 3.3uF
L4 5 0 0.35mH
RA 5 0 8

.options ACCT LIST NOMOD NOPAGE OPTS


.control 

*VOLCADO FICHERO.CIR ANALIZADO SINTACTICAMENTE
listing > filtroal.lst


*ANALISIS PUNTO DE OPERACION
op
rusage everything > op.ope
print  all > op.txt
display > op.var


*ANALISIS TRANSITORIO

*tran 1u 2u
*rusage everything > tran.ope
*print v(1) V(2) v(4) > tran.txt
*display > tran.var


*ANALISIS FRECUENCIA  [ac ( DEC | OCT | LIN ) N Fstart Fstop]

ac lin 200 10 30E3
rusage everything > ac.ope
plot mag(v(2)) mag(v(4)) mag(v(5)) xlimit 20 20k ylog xlog
*plot v(2) v(4) v(5) 
*xlimit 20 20k

print V(2) v(4) v(5) > ac.txt
display > ac.var
*asciiplot V(1) > ac.plt


.endc
.end


*  1) Ac        14) Echo      27) Plot      40) Setcirc   53) Tran      
*  2) Alias     15) Edit      28) Print     41) Setplot   54) Transpose 
*  3) Alter     16) Fourier   29) Quit      42) Settype   55) Unalias   
*  4) Asciiplot 17) Hardcopy  30) Rehash    43) Shell     56) Undefine  
*  5) Aspice    18) Help      31) Reset     44) Shift     57) Unset     
*  6) Bug       19) History   32) Reshape   45) Show      58) Version   
*  7) Cd        20) Iplot     33) Resume    46) Showmod   59) Where     
*  8) Destroy   21) Jobs      34) Rspice    47) Source    60) Write     
*  9) Dc        22) Let       35) Run       48) Status    61) Xgraph    
* 10) Define    23) Linearize 36) Rusage    49) Step      
* 11) Delete    24) Listing   37) Save      50) Stop      
* 12) Diff      25) Load      38) Sens      51) Tf        
* 13) Display   26) Op        39) Set       52) Trace

*     plot exprs [ylimit ylo yhi] [xlimit xlo xhi] [xindices xilo xihi]
*          [xcompress comp] [xdelta xdel] [ydelta ydel] [xlog] [ylog] [loglog]
*          [vs xname] [xlabel word] [ylabel word] [title word] [samep]
*          [linear]